今日まなび015：Grabパス

「今日まなび」は最低1日１ｈ、ゲーム作るために学びたいことなんでもいいから学んでいくコーナー。
完全自分用でまとめることは考えなくてＯＫ．１記事１ｈ。（１ｈでどんだけ学べるかのスピード感もみていきたいので）
１ｈのうちに次回学ぶことも決定しておくこと

環境：unity2021.3.40f

---

今日の学び

docs.unity3d.com

グラブパスは、GrabPass{}と定義した処理が呼ばれる時点の画面のレンダリング結果を取得できるもの。

これを使ってこれまで処理したレンダリング結果の色を反転させる例が以下。
別途テクスチャを設定して、その範囲だけ色が反転するようにしてみている。

Shader "Test/test015"
{
    Properties{
        _MainTex("Albedo", 2D) = "white" {}
    }

    SubShader
    {
        // すべての不透明のジオメトリの後に、自身を描画します
        Tags { "Queue" = "Transparent" } 

        // オブジェクトの後ろの画面を _BackgroundTexture 内に取得します
        GrabPass
        {
            "_BackgroundTexture"
        }

        // オブジェクトを上で生成したテクスチャと一緒にレンダリングし、カラーを反転します
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 grabPos : TEXCOORD0;
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD1;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            sampler2D _BackgroundTexture;


            v2f vert(appdata v) {
                v2f o;
                //  UnityCG.cginc の UnityObjectToClipPos  を使って 
                // 頂点のクリップスペースを計算します
                o.pos = UnityObjectToClipPos(v.vertex);
                // UnityCG.cginc の ComputeGrabScreenPos を使って 
                // 正しいテクスチャ座標を取得します
                o.grabPos = ComputeGrabScreenPos(o.pos);

                //テクスチャのUVを取得
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }


            half4 frag(v2f i) : SV_Target
            {
                //GrabPassの場合はこれまでのテクスチャで使っていた「tex2D」ではなく「tex2Dproj」を使う
                fixed4 gradCol = tex2Dproj(_BackgroundTexture, i.grabPos);
                fixed4 textureCol = tex2D(_MainTex, i.uv);

                clip(textureCol.a - 0.001);
                return 1 - gradCol;
            }
            ENDCG
        }
    }
}

このShaderを適応したQuad部分のみ色が反転している